从零开始的汇编语言笔记（3）

这里应该就是一些比较大的代码记录，其实就是课本题品鉴一下自己写一下。

[6.1] 编写一个子程序嵌套结构的程序模块，分别从键盘输入姓名及8个字符的电话号码，并以一定的格式显示出来。

主程序TELIST：

· 显示提示符INPUT NAME：；

· 调用子程序INPUT_NAME输入姓名；

· 显示提示符INPUT A TELEPHONE NUMBER：；

· 调用子程序INPHONE输入电话号码；

· 调用子程序PRINTLINE显示姓名及电话号码。

子程序INPUT_NAME：

· 调用键盘输入子程序GETCHAR，把输入的姓名存放在INBUF缓冲区中；

· 把INBUF中的姓名移入输出行OUTNAME。

子程序INPHONE：

· 调用键盘输入子程序GETCHAR，把输入的8位电话号码存放在INBUF缓冲区中；

· 把INBUF中的号码移入输出行OUTPHONE。

子程序PRINTLINE：

显示姓名及电话号码，格式为：
1
NAME    TEL.
2
X X X        XXXXXXXX

这是课本答案的代码：

1
;******************************************
2
; 数据段定义
3
DSEG        SEGMENT
4
    INBUF    DB  12 DUP (' ')            ; 输入缓冲区，初始化为空格，长度12个字节
5
    OUTNAME  DB  16 DUP (' ')            ; 姓名输出行，初始化为空格，长度16个字节
6
    OUTPHONE DB  12 DUP (' '), 0DH, 0AH, '$' ; 电话号码输出行，初始化为空格，后跟回车换行符和字符串结束符
7
    MESG1    DB  'INPUT  NAME：', '$'    ; 提示输入姓名的字符串
8
    MESG2    DB  'INPUT  A  TELEPHONE  NUMBER：', '$' ; 提示输入电话号码的字符串
9
    MESG3    DB  'NAME', 12 DUP (' '), 'TEL.', 0DH, 0AH, '$' ; 显示标题行的字符串
10
    CRLF     DB  0DH, 0AH, '$'          ; 回车换行符字符串
11
DSEG        ENDS                        ; 数据段结束
12
;******************************************
13

14
;******************************************
15
; 堆栈段定义
16
STACK       SEGMENT
17
    DW  100 DUP (?)                    ; 堆栈空间，100个字（200字节），未初始化
18
    TOS     LABEL  WORD                 ; 堆栈顶（Top of Stack）的标签
19
STACK       ENDS                        ; 堆栈段结束
20
;******************************************
21

22
;******************************************
23
; 代码段定义
24
CSEG        SEGMENT
25
; 主程序TELIST，远过程（FAR PROC）
26
TELIST      PROC    FAR
27
    ASSUME  CS: CSEG, DS: DSEG, ES: DSEG, SS: STACK ; 假设段寄存器的关联关系
28

29
; 初始化堆栈段寄存器SS和堆栈指针SP
30
START:      MOV     AX, STACK            ; 将堆栈段的段地址加载到AX
31
             MOV     SS, AX               ; 将AX的值（STACK段地址）赋给SS寄存器
32
             MOV     SP, OFFSET TOS        ; 将堆栈顶的偏移地址赋给SP寄存器
33

34
; 保存原有的数据段寄存器DS
35
             PUSH    DS                    ; 将DS压入堆栈，保存原始DS
36
             SUB     AX, AX                ; 将AX清零
37
             PUSH    AX                    ; 将AX（现在为0）压入堆栈，可能用于设置段寄存器
38
             MOV     AX, DSEG              ; 将数据段地址加载到AX
39
             MOV     DS, AX                ; 设置DS寄存器为DSEG
40
             MOV     ES, AX                ; 设置ES寄存器为DSEG
41

42
; 显示提示符“INPUT NAME：”
43
BEGIN:      LEA     DX, MESG1             ; 将MESG1的地址加载到DX
44
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
45
             INT     21H                   ; 调用DOS中断，显示字符串
46

47
             CALL    INPUT_NAME            ; 调用子程序INPUT_NAME，输入姓名
48

49
; 显示提示符“INPUT A TELEPHONE NUMBER：”
50
             LEA     DX, MESG2             ; 将MESG2的地址加载到DX
51
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
52
             INT     21H                   ; 调用DOS中断，显示字符串
53

54
             CALL    INPHONE               ; 调用子程序INPHONE，输入电话号码
55

56
             CALL    PRINTLINE             ; 调用子程序PRINTLINE，显示姓名及电话号码
57

58
             RET                            ; 远返回，结束主程序
59
TELIST      ENDP                          ; 主程序结束
60
;--------------------------------------------------------------------------
61

62
; 子程序INPUT_NAME，近过程（NEAR PROC）
63
INPUT_NAME  PROC    NEAR
64
             CALL    GETCHAR               ; 调用子程序GETCHAR，输入姓名
65

66
             LEA     SI, INBUF             ; 将INBUF的地址加载到SI（源索引寄存器）
67
             LEA     DI, OUTNAME           ; 将OUTNAME的地址加载到DI（目的索引寄存器）
68
             MOV     CX, 12                ; 设置循环计数器CX为12
69
             CLD                            ; 清除方向标志，字符串操作向前移动
70
             REP     MOVSB                 ; 重复移动字节，将INBUF的数据复制到OUTNAME
71

72
             RET                            ; 返回
73
INPUT_NAME  ENDP                          ; INPUT_NAME子程序结束
74
;--------------------------------------------------------------------------
75

76
; 子程序INPHONE，近过程（NEAR PROC）
77
INPHONE     PROC    NEAR
78
             CALL    GETCHAR               ; 调用子程序GETCHAR，输入电话号码
79

80
             LEA     SI, INBUF             ; 将INBUF的地址加载到SI（源索引寄存器）
81
             LEA     DI, OUTPHONE          ; 将OUTPHONE的地址加载到DI（目的索引寄存器）
82
             MOV     CX, 12                ; 设置循环计数器CX为12
83
             CLD                            ; 清除方向标志，字符串操作向前移动
84
             REP     MOVSB                 ; 重复移动字节，将INBUF的数据复制到OUTPHONE
85

86
             RET                            ; 返回
87
INPHONE     ENDP                          ; INPHONE子程序结束
88
;--------------------------------------------------------------------------
89

90
; 子程序GETCHAR，近过程（NEAR PROC）
91
GETCHAR     PROC    NEAR
92
             MOV     AL, 20H               ; 将空格字符（20H）加载到AL
93
             MOV     CX, 12                ; 设置循环计数器CX为12
94
             LEA     DI, INBUF             ; 将INBUF的地址加载到DI
95
             CLD                            ; 清除方向标志，字符串操作向前移动
96
             REP     STOSB                 ; 重复存储字节，将20H填充到INBUF
97

98
             MOV     CX, 12                ; 设置循环计数器CX为12，用于输入字符
99
             MOV     DI, 0                 ; 将DI清零，用于索引INBUF
100
INPUT:       MOV     AH, 1                 ; 设置AH为1，DOS读取字符功能
101
             INT     21H                   ; 调用DOS中断，读取一个字符
102

103
             CMP     AL, 0DH               ; 比较输入字符是否为回车符（0DH）
104
             JZ      QUIT                  ; 如果是回车符，跳转到QUIT
105

106
             MOV     [INBUF + DI], AL      ; 将输入的字符存入INBUF[DI]
107
             INC     DI                    ; 增加DI，指向下一个位置
108
             LOOP    INPUT                 ; 循环，直到CX为0
109
QUIT:        CALL    DISP_CRLF             ; 调用子程序DISP_CRLF，显示回车换行
110
             RET                            ; 返回
111
GETCHAR     ENDP                          ; GETCHAR子程序结束
112
;--------------------------------------------------------------------------
113

114
; 子程序PRINTLINE，近过程（NEAR PROC）
115
PRINTLINE   PROC    NEAR
116
             LEA     DX, MESG3             ; 将MESG3的地址加载到DX
117
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
118
             INT     21H                   ; 调用DOS中断，显示字符串
119

120
             LEA     DX, OUTNAME           ; 将OUTNAME的地址加载到DX
121
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
122
             INT     21H                   ; 调用DOS中断，显示姓名
123

124
             LEA     DX, OUTPHONE          ; 将OUTPHONE的地址加载到DX
125
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
126
             INT     21H                   ; 调用DOS中断，显示电话号码
127

128
             RET                            ; 返回
129
PRINTLINE   ENDP                          ; PRINTLINE子程序结束
130
;--------------------------------------------------------------------------
131

132
; 子程序DISP_CRLF，近过程（NEAR PROC）
133
DISP_CRLF   PROC    NEAR
134
             LEA     DX, CRLF              ; 将CRLF的地址加载到DX
135
             MOV     AH, 09H               ; 设置AH为09H，DOS显示字符串功能
136
             INT     21H                   ; 调用DOS中断，显示回车换行
137
             RET                            ; 返回
138
DISP_CRLF   ENDP                          ; DISP_CRLF子程序结束
139
;--------------------------------------------------------------------------
140

141
CSEG        ENDS                            ; 代码段结束
142
;******************************************
143

144
END     START                               ; 程序入口点

下面是我的代码：

1
dataseg segment
2
    prompt_name     db 'INPUT NAME: ', '$'
3
    prompt_phone    db 'INPUT A TELEPHONE NUMBER: ', '$'
4

5
    INBUF           db 20
6
    INBUF_LEN       db ?
7
    INBUF_DATA      db 20 dup(?)
8

9
    OUTNAME         db 20 dup(?)
10
    OUTPHONE        db 20 dup(?)
11

12
    prompt_title    db  'NAME', 8 DUP (' '), 'TEL.', 0DH, 0AH, '$'
13
dataseg ends
14

15
stackseg segment
16
    dw  100 dup(?)
17
    TOS label word
18
stackseg ends
19

20
codeseg segment
21
    assume cs: codeseg, ds: dataseg, ss: stackseg
22
TELIST proc far
23
start:
24
    mov ax, stackseg
25
    mov ss, ax
26
    mov sp, offset TOS
27

28
    push ds
29
    xor ax, ax
30
    push ax
31
    mov ax, dataseg
32
    mov ds, ax
33
    mov es, ax
34

35
    call INPUT_NAME
36
    call INPHONE
37

38
    call PRINTLINE
39

40
    pop ax
41
    pop ds
42
    mov ax, 4C00h
43
    int 21h
44

45
TELIST endp
46

47
INPUT_NAME proc near
48
    mov ah, 09h
49
    lea dx, prompt_name
50
    int 21h
51

52
    call GETCHAR
53
    mov cx, 0
54

55
    lea si, INBUF_DATA
56
    lea di, OUTNAME
57
    mov cl, INBUF_LEN
58
    cld
59
    rep movsb
60

61
    mov cl, 12
62
    sub cl, INBUF_LEN
63
    mov al, ' '
64
    rep stosb
65

66
    mov byte ptr [di], '$'
67

68
    ret
69
INPUT_NAME endp
70

71
INPHONE proc near
72
    mov ah, 09h
73
    lea dx, prompt_phone
74
    int 21h
75

76
    call GETCHAR
77

78
    lea si, INBUF_DATA
79
    lea di, OUTPHONE
80
    mov cl, INBUF_LEN
81
    cld
82
    rep movsb
83

84
    mov cl, 12
85
    sub cl, INBUF_LEN
86
    mov al, ' '
87
    rep stosb
88

89
    mov byte ptr [di], '$'
90
    ret
91
INPHONE endp
92

93
GETCHAR proc near
94
    mov ah, 0Ah
95
    lea dx, INBUF
96
    int 21h
97
    call newline
98
    ret
99
GETCHAR endp
100

101
newline proc near
102
    push ax
103
    push dx
104
    mov ah, 02h
105

106
    mov dl, 0Dh
107
    int 21h
108
    mov dl, 0Ah
109
    int 21h
110

111
    pop dx
112
    pop ax
113
    ret
114
newline endp
115

116
PRINTLINE proc near
117
    mov ah, 09h
118
    lea dx, prompt_title
119
    int 21h
120

121
    mov ah, 09h
122
    lea dx, OUTNAME
123
    int 21h
124

125
    mov ah, 09h
126
    lea dx, OUTPHONE
127
    int 21h
128

129
    ret
130
PRINTLINE endp
131
codeseg ends
132
end start